Visual basic 6 Ruská azbuka cyrilika.

Option Explicit
'
'UTF-8 version of this demo.
'
Private Sub Form_Load()
    Dim lngOrigColor As Long
    With New ADODB.Stream
        .Open
        .Type = adTypeText
        .Charset = "UTF-8"
        .LoadFromFile "Mak.txt"
        RTBWriteUnicode RichTextBox1, .ReadText(adReadAll), RTBW_DEFAULT
        .Close
    End With
End Sub

Private Sub Form_Resize()
    If WindowState <> vbMinimized Then
        RichTextBox1.Move 0, 0, ScaleWidth, ScaleHeight
    End If
End Sub

Option Explicit

Private Const CP_UNICODE = 1200
Private Const WM_USER = &H400&
Private Const EM_SETTEXTEX = WM_USER + 97

Private Declare Function SendMessageWLng Lib "user32" Alias "SendMessageW" ( _
    ByVal hWnd As Long, _
    ByVal wMsg As Long, _
    ByVal wParam As Long, _
    ByVal lParam As Long) As Long
   
Public Enum RTBW_FLAGS
    'Flags for the SETEXTEX data structure.
    RTBW_DEFAULT = 0   'Deletes undo stack, discards RTF formatting, replaces all text.
    RTBW_KEEPUNDO = 1  'Keeps undo stack.
    RTBW_SELECTION = 2 'Replaces selection and keeps RTF formatting.
End Enum
'Force IDE to maintain the case of these constant names.
#If False Then
Dim RTBW_DEFAULT
Dim RTBW_KEEPUNDO
Dim RTBW_SELECTION
#End If

Private Type SETTEXTEX
    flags As RTBW_FLAGS
    codepage As Long
End Type

Public Sub RTBWriteUnicode( _
    ByRef RTB As RichTextLib.RichTextBox, _
    ByRef Text As String, _
    Optional ByVal flags As RTBW_FLAGS = RTBW_DEFAULT)
    'Writes Text to RichTextBox as Unicode text on a system with Rich Edit 3.0
    '(Windows Me, Windows 2000, or later).
    '
    'Caution/Feature:
    '   If Text begins with a valid RTF sequence such as "{\rtf" or "{urtf" the
    '   text is taken as RTF instead of plain text.
    Dim stUnicode As SETTEXTEX
   
    With stUnicode
        .flags = flags
        .codepage = CP_UNICODE
    End With
    If SendMessageWLng(RTB.hWnd, EM_SETTEXTEX, VarPtr(stUnicode), StrPtr(Text)) = 0 Then
        Err.Raise &H4008AA00, "WriteUnicodeText", "Failed: insufficient space available"
    End If
End Sub

Option Explicit
'
'Some VB6 controls, despite being "ANSI" in nature, do indeed
'support international codepages via their Font.Charset
'property.
'
'This example reads the contents of UTF-16LE text files that
'contain Russian text and displays this in conventional VB6
'intrinsic controls.
'
'Note that the Charset of these controls has been set at design
'time via the Font property dialog in the IDE.
'

Private Const LCID_Russian = 1049

Private Function GetUnicode(ByVal Filename As String) As String
    'Use binary I/O to read UTF-16LE file into a Unicode String.
    Dim intFile As Integer
    Dim bytBuffer() As Byte

    intFile = FreeFile(0)
    Open Filename For Binary Access Read As #intFile
   
    'Skip BOM if present.
    ReDim bytBuffer(1)
    Get #intFile, , bytBuffer
    If bytBuffer(0) = &HFF And bytBuffer(1) = &HFE Then
        ReDim bytBuffer(LOF(intFile) - 3)
    Else
        ReDim bytBuffer(LOF(intFile) - 1)
        Seek #intFile, 1
    End If
   
    Get #intFile, , bytBuffer
    Close #intFile
    GetUnicode = bytBuffer
End Function

Private Function LocalizeANSI(ByVal Expression As String, _
                              ByVal LCID As Long) As String
    'Converts Unicode String "Expression" to ANSI using an alternate
    'LCID, then converts the result back to Unicode using the current
    'system LCID.
    '
    'This scrambles the data, but in such a way that a VB6 control's
    'Font.Charset property can accomplish proper symbol mapping.
    Dim bytBuffer() As Byte

    bytBuffer = StrConv(Expression, vbFromUnicode, LCID)
    LocalizeANSI = StrConv(bytBuffer, vbUnicode)
End Function

Private Sub Form_Load()
    Label1.Caption = LocalizeANSI(GetUnicode("russian caption.txt"), LCID_Russian)
    Text1.Text = LocalizeANSI(GetUnicode("russian.txt"), LCID_Russian)
End Sub

Private Sub Form_Resize()
Text1.Move Text1.Left, Text1.Top, ScaleWidth, ScaleHeight - Text1.Top
End Sub